chromium/chrome/android/features/cablev2_authenticator/BUILD.gn

# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/rules.gni")
import("//chrome/android/modules/buildflags.gni")
import("//third_party/jni_zero/jni_zero.gni")

android_library("java") {
  srcjar_deps = [ ":jni_headers" ]
  sources = [
    "java/src/org/chromium/chrome/browser/webauth/authenticator/BLEAdvert.java",
    "java/src/org/chromium/chrome/browser/webauth/authenticator/CableAuthenticator.java",
    "java/src/org/chromium/chrome/browser/webauth/authenticator/CableAuthenticatorUI.java",
    "java/src/org/chromium/chrome/browser/webauth/authenticator/USBHandler.java",
  ]

  deps = [
    ":java_resources",
    "$google_play_services_package:google_play_services_base_java",
    "$google_play_services_package:google_play_services_tasks_java",
    "//base:base_java",
    "//build/android:build_java",
    "//chrome/browser/webauthn/android:java_resources",
    "//components/webauthn/android:java",
    "//content/public/android:content_java",
    "//mojo/public/mojom/base:base_java",
    "//services/device/public/java:device_feature_list_java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_core_core_java",
    "//third_party/androidx:androidx_fragment_fragment_java",
    "//third_party/androidx:androidx_vectordrawable_vectordrawable_animated_java",
    "//third_party/blink/public/mojom:android_mojo_bindings_java",
    "//third_party/jni_zero:jni_zero_java",
    "//ui/android:ui_full_java",
    "//url:gurl_java",
  ]

  resources_package = "org.chromium.chrome.browser.webauth.authenticator"
}

generate_jni("jni_headers") {
  sources = [
    "java/src/org/chromium/chrome/browser/webauth/authenticator/BLEAdvert.java",
    "java/src/org/chromium/chrome/browser/webauth/authenticator/CableAuthenticator.java",
    "java/src/org/chromium/chrome/browser/webauth/authenticator/USBHandler.java",
  ]
  split_name = "cablev2_authenticator"
}

android_resources("java_resources") {
  sources = [
    "java/res/drawable-night/ble.xml",
    "java/res/drawable-night/cable_qr_code.xml",
    "java/res/drawable/ble.xml",
    "java/res/drawable/cable_qr_code.xml",
    "java/res/drawable/usb_conn_disconnect.xml",
    "java/res/layout-sw600dp/cablev2_ble_enable.xml",
    "java/res/layout-sw600dp/cablev2_qr.xml",
    "java/res/layout/cablev2_ble_enable.xml",
    "java/res/layout/cablev2_qr.xml",
    "java/res/layout/cablev2_usb_attached.xml",
    "java/res/values/attrs.xml",
  ]
  deps = [ "//chrome/android:chrome_app_java_resources" ]
}

source_set("native") {
  sources = [ "native/cablev2_authenticator_android.cc" ]

  deps = [
    ":jni_headers",
    "//base",
    "//components/cbor",
    "//components/device_event_log",
    "//content/public/browser",
    "//crypto",
    "//device/fido",
    "//device/fido:cablev2_authenticator",
    "//device/fido:cablev2_registration",
    "//third_party/boringssl",
  ]

  # caBLE v2 authenticator native entrypoints belong in the partition.
  if (use_native_partitions) {
    cflags = [ "-fsymbol-partition=cablev2_authenticator_partition" ]
  }
}