llvm/llvm/utils/gn/secondary/llvm/tools/llvm-dwp/BUILD.gn

import("//llvm/tools/binutils_symlinks.gni")
import("//llvm/utils/gn/build/driver_executable.gni")
import("//llvm/utils/gn/build/symlink_or_copy.gni")
import("//llvm/utils/TableGen/tablegen.gni")

tablegen("Opts") {
  visibility = [ ":llvm-dwp" ]
  args = [ "-gen-opt-parser-defs" ]
}

if (llvm_install_binutils_symlinks) {
  symlink_or_copy("dwp") {
    deps = [ ":llvm-dwp" ]
    source = "llvm-dwp"
    output = "$root_out_dir/bin/dwp"
  }
}

# //:llvm-dwp depends on this symlink target, see comment in //BUILD.gn.
group("symlinks") {
  deps = [ ":llvm-dwp" ]
  if (llvm_install_binutils_symlinks) {
    deps += [ ":dwp" ]
  }
}

driver_executable("llvm-dwp") {
  deps = [
    ":Opts",
    "//llvm/lib/DWP",
    "//llvm/lib/DebugInfo/DWARF",
    "//llvm/lib/MC",
    "//llvm/lib/Object",
    "//llvm/lib/Option",
    "//llvm/lib/Support",
    "//llvm/lib/Target:TargetsToBuild",
    "//llvm/lib/TargetParser",
  ]
  sources = [ "llvm-dwp.cpp" ]
}